Invokes an editor to edit the previous command or statement, one
       or more types of object definitions, or the dictionary object
       specified by the dictionary path name.

       Format

               [           {DOMAINS     }                    ]
               [           {PLOTS       }                    ]
               [           {            }                    ]
               [   [ALL]   {PROCEDURES  }  [,...]  [RECOVER] ]
               [           {RECORDS     }                    ]
         EDIT  [           {TABLES      }                    ]
               [                                             ]
               [                                             ]
               [   ALL  [RECOVER]                            ]
               [                                             ]
               [   [path-name]  [RECOVER]                    ]
               [                                             ]

1  –  Arguments

    ALL

       Places all the objects in your Oracle CDD/Repository default
       directory in an editing buffer. The keyword ALL is optional when
       used with the object types, but required when used alone or with
       only RECOVER.

    path-name

       Is the given name, full dictionary path name, or relative path
       name of a DEC DATATRIEVE domain, record, procedure, or table
       definition you want to edit. EDIT accepts both DMU and CDO style
       path names.

    DOMAINS

       You can specify one or more types of object definitions with the
       EDIT command. This allows you to edit all the domains, plots,
       procedures, records, or tables from your current default Oracle
       CDD/Repository directory.

    RECOVER

       Allows recovery for edited dictionary objects.

2  –  Example

       The following example shows how to edit the definition for the
       record YACHT:

       DTR> EDIT YACHT
       REDEFINE RECORD YACHT USING
       01 BOAT.
         03 TYPE.
            06 MANUFACTURER PIC X(10)
               QUERY_NAME IS BUILDER.
            06 MODEL PIC X(10).
         03 SPECIFICATIONS
            QUERY_NAME SPECS.
            06 RIG PIC X(6)
               VALID IF RIG EQ "SLOOP","KETCH","MS","YAWL".
            06 LENGTH_OVER_ALL PIC XXX
               VALID IF LOA BETWEEN 15 AND 50
               QUERY_NAME IS LOA.
            06 DISPLACEMENT PIC 99999
               QUERY_HEADER IS "WEIGHT"
               EDIT_STRING IS ZZ,ZZ9
               QUERY_NAME IS DISP.
            06 BEAM PIC 99 MISSING VALUE IS 0.
            06 PRICE PIC 99999
               MISSING VALUE IS 0
               VALID IF PRICE>DISP*1.3 OR PRICE EQ 0
               EDIT_STRING IS $$$,$$$.
       ;
       [Record is 41 bytes long.]

       You can now edit the record definition. If SET EDIT_BACKUP is in
       effect, the old version of the YACHT record is retained in the
       data dictionary when you exit the editor.