$!------------------------------------------------------------------------------
$! MMS_SETUP.COM -- Set up the build sub-process for WASD
$!------------------------------------------------------------------------------
$!
$ Set NoOn
$ Verify = F$VERIFY(0)
$!
$!------------------------------------------------------------------------------
$ Set := Set							!Sanity check
$ Set Symbol/Verb/Scope=(NoLocal,NoGlobal)			!No strange commands allowed
$ Proc = F$Environment("Procedure")				!Get our procedure name
$ Arch = F$GetSyi("ARCH_NAME")
$ defroot := Define/NoLog/Translation=(Concealed, Terminal)
$!
$!------------------------------------------------------------------------------
$! Make sure WASD_ROOT is defined.
$!------------------------------------------------------------------------------
$ device = F$Parse("[-]",Proc,,"Device","No_Conceal")
$ local_dir = F$Parse("[-]",Proc,,"Directory","No_Conceal")
$ wasd_root = device + local_dir - ".][000000" - "]" + ".]"
$ defroot WASD_ROOT 'wasd_root'
$!
$!------------------------------------------------------------------------------
$! Multinet defines this, TCPIP Services doesn't
$! This way, the build process can simply include TCPIP$IPC_SHR/SHARE
$!------------------------------------------------------------------------------
$!
$ If F$TRNLNM("TCPIP$IPC_SHR") .Eqs. "" Then DEFINE/NOLOG TCPIP$IPC_SHR SYS$LIBRARY:TCPIP$IPC_SHR.EXE
$!
$!------------------------------------------------------------------------------
$! Get the package version into a variable
$!------------------------------------------------------------------------------
$ SEARCH [.HTTPD]VERSION.H HTTPD_VERSION /OUTPUT=IMAGE_IDENT.LIS
$ OPEN /READ IMAGEIDENT IMAGE_IDENT.LIS
$ READ IMAGEIDENT IDENT
$ CLOSE IMAGEIDENT
$ DELETE /NOLOG /NOCONFIRM IMAGE_IDENT.LIS;*
$ IMAGE_IDENT == F$ELEMENT(1,"""",IDENT)
$ IF IMAGE_IDENT .EQS. "" .OR. IMAGE_IDENT .EQS. """" -
     THEN IMAGE_IDENT == "_UNKNOWN_"
$!
$!------------------------------------------------------------------------------
$! Process the parameters this procedure supports
$!   P1 = SSL Library to use
$!	Blank = build using latest VSI sharable library (currently V3.0)
$!	SSL31   = build using VSI SSL31 sharable library (V3.1)
$!	OLB31	= build using VSI SSL31 object library (V3.1)
$!	SSL3   = build using VSI SSL3 sharable library (V3.0)
$!	OLB3	= build using VSI SSL3 object library (V3.0)
$!	SSL111 = build using VSI SSL111 sharable library (V1.1.1)
$!	OLB111	= build using VSI SSL111 object library (V1.1.1)
$!------------------------------------------------------------------------------
$!
$ SSLVER = P1
$ IF SSLVER .EQS. "" THEN SSLVER = "SSL3"	! Current default
$!
$ IF SSLVER .EQS. "SSL31" .OR. SSLVER .EQS. "OLB31"
$  THEN
$    DEFINE /NOLOG OPENSSL      SSL31$INCLUDE
$    DEFINE /NOLOG SSL_LIBCRYPTO32 SSL31$LIB:SSL31$LIBCRYPTO32.OLB
$    DEFINE /NOLOG SSL_LIBSSL32  SSL31$LIB:SSL31$LIBSSL32.OLB
$    DEFINE /NOLOG SSL_LIBCRYPTO64 SSL31$LIB:SSL31$LIBCRYPTO.OLB
$    DEFINE /NOLOG SSL_LIBSSL64  SSL31$LIB:SSL31$LIBSSL.OLB
$    DEFINE /NOLOG SSL_SHRCRYPTO32 SYS$LIBRARY:SSL31$LIBCRYPTO_SHR32.EXE
$    DEFINE /NOLOG SSL_SHRSSL32  SYS$LIBRARY:SSL31$LIBSSL_SHR32.EXE
$    DEFINE /NOLOG SSL_SHRCRYPTO64 SYS$LIBRARY:SSL31$LIBCRYPTO_SHR.EXE
$    DEFINE /NOLOG SSL_SHRSSL64  SYS$LIBRARY:SSL31$LIBSSL_SHR.EXE
$    SESOLA_SHARE == SSLVER .EQS. "SSL31"
$    GOTO SSLEND
$  ENDIF
$ IF SSLVER .EQS. "SSL3" .OR. SSLVER .EQS. "OLB3"
$  THEN
$    DEFINE /NOLOG OPENSSL      SSL3$INCLUDE
$    DEFINE /NOLOG SSL_LIBCRYPTO32 SSL3$LIB:SSL3$LIBCRYPTO32.OLB
$    DEFINE /NOLOG SSL_LIBSSL32  SSL3$LIB:SSL3$LIBSSL32.OLB
$    DEFINE /NOLOG SSL_LIBCRYPTO64 SSL3$LIB:SSL3$LIBCRYPTO.OLB
$    DEFINE /NOLOG SSL_LIBSSL64  SSL3$LIB:SSL3$LIBSSL.OLB
$    DEFINE /NOLOG SSL_SHRCRYPTO32 SYS$LIBRARY:SSL3$LIBCRYPTO_SHR32.EXE
$    DEFINE /NOLOG SSL_SHRSSL32  SYS$LIBRARY:SSL3$LIBSSL_SHR32.EXE
$    DEFINE /NOLOG SSL_SHRCRYPTO64 SYS$LIBRARY:SSL3$LIBCRYPTO_SHR.EXE
$    DEFINE /NOLOG SSL_SHRSSL64  SYS$LIBRARY:SSL3$LIBSSL_SHR.EXE
$    SESOLA_SHARE == SSLVER .EQS. "SSL3"
$    GOTO SSLEND
$  ENDIF
$ IF SSLVER .EQS. "SSL111" .OR. SSLVER .EQS. "OLB111"
$  THEN
$    DEFINE /NOLOG OPENSSL      SSL111$INCLUDE
$    DEFINE /NOLOG SSL_LIBCRYPTO32 SSL111$LIB:SSL111$LIBCRYPTO32.OLB
$    DEFINE /NOLOG SSL_LIBSSL32  SSL111$LIB:SSL111$LIBSSL32.OLB
$    DEFINE /NOLOG SSL_LIBCRYPTO64 SSL111$LIB:SSL111$LIBCRYPTO.OLB
$    DEFINE /NOLOG SSL_LIBSSL64 SSL111$LIB:SSL111$LIBSSL.OLB
$    DEFINE /NOLOG SSL_SHRCRYPTO32 SYS$LIBRARY:SSL111$LIBCRYPTO_SHR32.EXE
$    DEFINE /NOLOG SSL_SHRSSL32  SYS$LIBRARY:SSL111$LIBSSL_SHR32.EXE
$    DEFINE /NOLOG SSL_SHRCRYPTO64 SYS$LIBRARY:SSL111$LIBCRYPTO_SHR.EXE
$    DEFINE /NOLOG SSL_SHRSSL64  SYS$LIBRARY:SSL111$LIBSSL_SHR.EXE
$    SESOLA_SHARE == SSLVER .EQS. "SSL111"
$    GOTO SSLEND
$  ENDIF
$ IF SSLVER .EQS. "WASD111"
$  THEN
$     WRITE SYS$OUTPUT "(Note: WASD OpenSSL no longer supported)"
$  ENDIF
$!
$ WRITE SYS$OUTPUT "Fatal: Unrecognized SSL version specified (''SSLVER')."
$ LOGOUT/BRIEF
$!
$SSLEND:
$!
$!------------------------------------------------------------------------------
$! Exit the procedure
$!------------------------------------------------------------------------------
$!
$ALLDONE:
$ Verify = F$VERIFY(Verify)
$!
$ EXIT