* Copyright © Oracle Corporation 1995.  All Rights Reserved.
IDENTIFICATION DIVISION.
PROGRAM-ID.	RDB_DEL_WEST	INITIAL.
*
* This subprogram is called by the program SQL$DIST_TRANS.COB.  It calls
* SQL module procedures to delete an employee record from the WEST database, 
* an Oracle Rdb database.

DATA DIVISION.
WORKING-STORAGE SECTION.
*
* Declare the SQLCODE.
    01  SQLCODE			PIC S9(9) COMP.

*
* Declare the context structure.
    01  CONTEXT.
    	05  CONTEXT-VERSION	PIC 9(9) COMP.
    	05  CONTEXT-TYPE	PIC 9(9) COMP.
    	05  CONTEXT-LENGTH	PIC 9(9) COMP.
    	05  CONTEXT-TID.
            10  LOW_DATE	PIC 9(9) COMP.
            10  HIGH_DATE	PIC 9(9) COMP.
    	    10  DATE_INCARN	PIC 9(4) COMP.
     	    10  NODE_ID		PIC 9(4) COMP.
     	    10  NODE_IDH	PIC 9(9) COMP.
    	05  CONTEXT-END		PIC 9(9) COMP.



LINKAGE SECTION.
*
* Employee ID collected in this program for return to SQL$DIST_TRANS.
    01  EMPLOYEE-ID		PIC X(5).

*
* The distributed TID from SQL$DIST_TRANS to be passed to SQL.
    01  TID.
        05  LOW_DATE		PIC 9(9) COMP.
        05  HIGH_DATE		PIC 9(9) COMP.
    	05  DATE_INCARN		PIC 9(4) COMP.
     	05  NODE_ID		PIC 9(4) COMP.
     	05  NODE_IDH		PIC 9(9) COMP.





PROCEDURE DIVISION USING EMPLOYEE-ID, TID.
MAIN-SECTION.

*
* Initialize the context record
    MOVE 1 TO CONTEXT-VERSION.
    MOVE 1 TO CONTEXT-TYPE.
    MOVE 16 TO CONTEXT-LENGTH.
    MOVE CORRESPONDING TID TO CONTEXT-TID.
    MOVE ZERO TO CONTEXT-END.

*
* Get the employee ID.
    DISPLAY "".
    DISPLAY "$ Please enter the ID of the employee: " WITH NO ADVANCING.
    ACCEPT EMPLOYEE-ID.

*
* Call the SQL module procedure START_WEST to start the transaction.
    CALL "START_WEST" USING SQLCODE, CONTEXT.
    IF SQLCODE LESS THAN ZERO THEN
    	CALL "SQL$DIST_TRANS_ERROR" USING TID, SQLCODE.

*
* Call the SQL module procedure DELETE_WEST to delete the employee record.
    DISPLAY "".
    DISPLAY "Deleting the row in 2pcwest database".
    CALL "DELETE_WEST" USING SQLCODE, EMPLOYEE-ID, CONTEXT. 
    IF SQLCODE LESS THAN ZERO THEN
    	CALL "SQL$DIST_TRANS_ERROR" USING TID, SQLCODE.
    IF SQLCODE EQUAL 100 THEN
    	CALL "SQL$DIST_TRANS_ERROR" USING TID, SQLCODE.

    EXIT PROGRAM.