$!-----------------------------------------------------------------------------
$! BUILD_DCLINABOX.COM
$!
$! P1 == LINK or BUILD or empty (builds)
$!
$! 16-JUL-2016  MGD  cleanup
$! 04-DEC-2011  MGD  initial
$!-----------------------------------------------------------------------------
$!
$ ON CONTROLY THEN EXIT 44
$!
$ WRITE SYS$OUTPUT ""
$ WRITE SYS$OUTPUT "Building ""DCLINABOX""" +-
                   " for ""''F$GETSYI("ARCH_NAME")'"" architecture"
$!
$ ARCH_NAME = F$EDIT(F$GETSYI("ARCH_NAME"),"UPCASE")
$ IF ARCH_NAME .EQS. "ALPHA" THEN ARCH_NAME = "AXP"
$ IF ARCH_NAME .EQS. "VAX" THEN EXIT 44
$!
$ DEFINES = " /DEFINE=(__VMS_VER=70000000,__CRTL_VER=70000000)"
$ INCLUDES = " /INCLUDE=([SRC.MISC])"
$ WARNINGS=  " /WARNING=(DISABLE=(PREOPTW,IMPLICITFUNC,ADDRCONSTEXT))"
$!
$ CC_OPTIONS = "/DECC /OPTIMIZE /STAND=RELAXED_ANSI /PREFIX=ALL" +-
               INCLUDES + DEFINES + WARNINGS
$!
$ IF P1 .EQS. "LIST"
$ THEN
$    CC_OPTIONS = CC_OPTIONS + "/LIST/MACHINE"
$    P1 = ""
$ ENDIF
$!
$ IF F$SEARCH("OBJ_''ARCH_NAME'.DIR") .EQS. "" -
     THEN CREATE /DIR [.OBJ_'ARCH_NAME']
$ OBJECT_DIR = "[.OBJ_''ARCH_NAME']"
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "COMPILE"
$ THEN
$    SET NOON
$    SET VERIFY
$    CC 'CC_OPTIONS' /NODEBUG/OBJECT='OBJECT_DIR' -
                     DCLINABOX+SYS$LIBRARY:SYS$LIB_C/LIB
$    CC 'CC_OPTIONS' /OBJECT='OBJECT_DIR' WSLIB
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$!
$ IF P1 .EQS. "" .OR. P1 .EQS. "BUILD" .OR. P1 .EQS. "LINK"
$ THEN
$    SET NOON
$    SET VERIFY
$    LINK /NOTRACE/SYSEXE/EXECUTABLE=WASD_EXE:DCLINABOX.EXE -
     'OBJECT_DIR'DCLINABOX,'OBJECT_DIR'WSLIB
$!   'F$VERIFY(0)
$    SET ON
$ ENDIF
$ PURGE /NOLOG 'OBJECT_DIR'
$!
$! (cleanup following v1.3)
$ if f$search("wasd_root:[runtime.dclinabox]usercss*.css") .nes. "" -
     then delete/nolog wasd_root:[runtime.dclinabox]usercss*.css;*
$ if f$search("wasd_root:[runtime.dclinabox]*.gif") .nes. "" -
     then delete/nolog wasd_root:[runtime.dclinabox]*.gif;*
$ if f$search("wasd_root:[runtime.dclinabox]*.ico") .nes. "" -
     then delete/nolog wasd_root:[runtime.dclinabox]*.ico;*
$ if f$search("wasd_root:[runtime.dclinabox]*.png") .nes. "" -
     then delete/nolog wasd_root:[runtime.dclinabox]*.png;*
$!
$!-----------------------------------------------------------------------------